***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Apr. 22, 2025                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt   PJQ4524P-AU     drain  gate  source
Lg     gate  g1    2.2n
Ld     drain d1    100p
Ls     source s1   350p
Rs      s1    s2   205u TC=3m
Rg     g1    g2     0.878
M1      d2    g2    s2    s2    DMOS    L=1u   W=1u
.MODEL DMOS NMOS ( KP=300.1  VTO=2.4  LEVEL=3  VMAX=5e4  ETA=0.006  NFS=6.733e11  GAMMA=0.8)
Rd     d1    d2    2.95m    TC=3.5m,3u
Dbd     s2    d2    Dbt
.MODEL   Dbt   D(BV=33  TBV1=3.898e-4 TBV2=-1.57e-7  CJO=1.688e-9  M=7.811e-1  VJ=7.138)
Dbody   s2   21    DBODY
.MODEL DBODY  D(IS=8.901e-12  N=1.04  RS=4e-8  EG=1.12  TT=20n IKF=6.347e+1 TIKF=9.801e-3)
Rdiode  d1  21    2.319e-3 TC=4.5m
.MODEL   sw    NMOS(VTO=0  KP=10   LEVEL=1)
Maux      g2   c    a    a   sw
Maux2     b    d    g2    g2   sw
Eaux      c    a    d2    g2   1
Eaux2     d    g2   d2    g2   -1
Cox       b    d2   2.687e-10
.MODEL     DGD    D(CJO=2.687e-10   M=1.458   VJ=6.784)
Rpar      b    d2   10Meg
Dgd       a    d2   DGD
Rpar2     d2   a    10Meg
Cgs     g2    s2    1.072e-9
.ENDS PJQ4524P-AU
*$
